Ticket #22: sendinpaths.pl

#!/usr/bin/perl
#
# replacement for the sendinpaths.sh shell script.
# assumes you already have ninpaths installed in $inn::pathbin
#

require '/news/lib/innshellvars.pl';

use Getopt::Std;

$pathhost    = "$inn::pathhost";
$ninpaths    = "$inn::pathbin/ninpaths";
$ninpathsdir = "$inn::pathlog/path";
$reportdays  = 30;
$keepdays    = 14;
$emailto     = "top1000\@anthologeek.net";
$ccto        = "usenet";
$sendmail    = "/usr/sbin/sendmail";
$debug       = 0;

sub usage {
        print <<_end_;
Usage:
        $0 [-dnh] [email]

        If called without any arguments, reports are generated and auto
        submitted to the respective inpaths accumulation site.

        -d:     enable debug messages
        -n:     gathers stats, but does not auto-submit emails
        -h:     this help message

        current default submit address: [$emailto]
        the optional argument [email] may be used to override this default.
_end_
        exit(1);
}

sub main {
        my (@files, @validfiles, @oldfiles);
        my ($file, $path, $appendargs, $sendout, $cmd);

        getopts('dnh') || &usage;
        &usage if ( $opt_h );

        # if we took an email argument
        $emailto = $ARGV[0] if ( $ARGV[0] );

        # set debug
        $debug = 1 if ( $opt_d );

        # make it simple
        $path = $ninpathsdir;

        # we'll need to scan the ninpaths directory
        opendir(DIR, $path) || die "can't open $path, $!\n";
        @files = readdir(DIR);
        closedir(DIR);

        foreach $file (@files) {
                next if ( ! -f "$path/$file" );

                # get a listing of all the valid files to process
                if ( -s _ && int(-M _) < $reportdays ) {
                        push @validfiles, $file;
                }

                # now get the list of all files that will be removed
                if ( int(-M _) > $keepdays ) {
                        push @oldfiles, $file;
                }
        }

        chdir($ninpathsdir);

        # process each dump
        foreach $file (@validfiles) {
                $cmd = "$ninpaths -u $file -r $pathhost";

                printf(STDERR "execing %s\n", $cmd) if ( $debug );

                open(NINPATHS, "$cmd |") || next;
                while (<NINPATHS>) {
                        ;
                }
                close(NINPATHS);

                if ( $? == 0 ) {
                        $appendargs .= " -u $file";
                }
        }

        # prepare to send reports, and purge old entries from disk
        $cmd = "$ninpaths $appendargs -r $pathhost";

        printf(STDERR "execing %s\n", $cmd) if ( $debug );

        open(NINPATHS, "$cmd |");
        while (<NINPATHS>) {
                $sendout .= $_;
        }
        close(NINPATHS);

        if ( $opt_n ) {
                # we are not sending this report anywhere, but to stdout
                print $sendout;
        } else {
                open(SENDMAIL, "| $sendmail -oi -t");
                print SENDMAIL "To: ", $emailto, "\n";
                print SENDMAIL "Cc: ", $ccto, "\n";
                print SENDMAIL "Subject: inpaths ", $pathhost, "\n";
                print SENDMAIL "\n";
                print SENDMAIL $sendout;
                print SENDMAIL "\n";
                close(SENDMAIL);

                # now remove old dumps
                foreach $file (@oldfiles) {
                        printf(STDERR "unlinking %s\n", $file) if ( $debug );
                        unlink($file);
                }
        }

        return 0;
}

&main;

0;